This lecture will cover how to write SAS MACROS. SAS MACROS are how users can define their own functions to automate repetitive code. We will cover
For this lecture, we will use the Framingham dataset which was a large longitudinal, epidemiologice study of the risks of heart disease. Before we get started with MACROS, let's load the dataset and explore it a little.
LIBNAME myData "H:\BiostatCourses\PublicHealthComputing\Lectures\Week4Macros_Functions\SAS";
PROC CONTENTS DATA = myData.fghm113;
RUN;
We will add the following translations to the dataset.
SEX (Gender): 1=Men
2=Women
Period (Examination cycle): 1=Period1
2=Period2
3=Period3
BPMEDS (Use of anti-hypertensive meds): 0=Not currently
1=Currently use
CURSMOKE (Currently smoke?): 0=No
1=Yes
DIABETES: 0=Not diabetic
1=Diabetic
PREVAP (Have angina pectoric?): 0=No
1=Yes
PREVCHD (Coronary heart disease?): 0=No
1=Yes
PREVMI (Myocardial infarction?): 0=No
1=Yes
PREVSTRK (Had a stroke?): 0=No
1=Yes
PREVHYP (Hypertensive? sys bp >=140 or dyas bp >= 90): 0=no
1=yes
DATA fghmTemp;
SET myData.fghm113;
RUN;
PROC FORMAT;
VALUE YNfmt 0="No"
1="Yes";
VALUE perfmt 1="Period 1"
2="Period 2"
3="Period 3";
VALUE gndrfmt 1="Men"
2="Women";
RUN;
DATA fghmtemp;
SET fghmtemp;
FORMAT prevap ynfmt.
diabetes ynfmt.
cursmoke ynfmt.
bpmeds ynfmt.
prevchd ynfmt.
prevmi ynfmt.
prevstrk ynfmt.
prevhyp ynfmt.
sex gndrfmt.;
RUN;
*Check to see if the formatting was done correctly;
PROC CONTENTS DATA = fghmtemp;
RUN;
PROC PRINT DATA = fghmtemp (obs=5);
RUN;
%LET creates a MACRO variable. MACRO variables allow us to store text such as the varaible name in our dataset of the p-value from a table in a variable for use later. We can reference the value of the macro variable by placing & before the macro variable name.
Let's use MACRO variables to explore the relationship between begin diabetic and having coronary hearth disease.
PROC FREQ DATA = fghmtemp;
TABLE diabetes*prevchd / CHISQ;
RUN;
%LET response = prevchd;
%LET predictor = diabetes;
%LET dataset = fghmtemp;
*&predictor will put diabetes into the SAS code;
PROC FREQ DATA = &dataset;
TITLE "&predictor vs &response";
TABLE &predictor*&response / CHISQ;
RUN;
TITLE;
%SYMDEL dataset predictor response;
All macros start with %MACRO and end with %MEND. First, let's make a simple macro to create a two by two contingency table with chi-square test results.
In general, when writing a MACRO, we need to write a non macro version to test the code. Then, we can make it into a MACRO by subbing in the macro variabes. In this case, we have already written the code above.
%MACRO twobytwo(dataset, predictor, response);
PROC FREQ DATA = &dataset;
TITLE "&predictor vs &response";
TABLE &predictor*&response / CHISQ;
RUN;
TITLE;
%MEND;
*Call the MACRO function;
%twobytwo(fghmtemp, diabetes, prevchd);
When creating macros, it is not uncommon to have to debug them. SAS provides some useful debugging options for macros.
OPTIONS SYMBOLGEN;
OPTIONS MPRINT;
OPTIONS MLOGIC;
%twobytwo(fghmtemp, prevstrk, prevchd);
OPTIONS NOSYMBOLGEN;
OPTIONS NOMPRINT;
OPTIONS NOMLOGIC;
The code above results in the following output in the log file.
MLOGIC(TWOBYTWO): Beginning execution. MLOGIC(TWOBYTWO): Parameter DATASET has value fghmtemp MLOGIC(TWOBYTWO): Parameter PREDICTOR has value prevstrk MLOGIC(TWOBYTWO): Parameter RESPONSE has value prevchd SYMBOLGEN: Macro variable DATASET resolves to fghmtemp MPRINT(TWOBYTWO): PROC FREQ DATA = fghmtemp; SYMBOLGEN: Macro variable PREDICTOR resolves to prevstrk SYMBOLGEN: Macro variable RESPONSE resolves to prevchd MPRINT(TWOBYTWO): TITLE "prevstrk vs prevchd"; SYMBOLGEN: Macro variable PREDICTOR resolves to prevstrk SYMBOLGEN: Macro variable RESPONSE resolves to prevchd MPRINT(TWOBYTWO): TABLE prevstrk*prevchd / CHISQ; MPRINT(TWOBYTWO): RUN;
The macro %DO can be used outside of a PROC or DATA step (unlike a regulat DO loop), which will allow us to loop through different procedures or data steps inside a macro.
For the next example, we will examine if there is an association between being diabetic and the other adverse health outcomes: coronary heart disease (prevchd), myocardial infarction (prevmi), stroke (precstrk), angine pectoris (prevap), or hypertension (prevhyp).
To do this, we will make a contingency table for each of these pairs of variables and get a chi-squared test and Fisher's exact test results.
We could write out the PROC FREQ statement for each of these 5 pairs.
PROC FREQ DATA = fghmtemp;
TABLE prevap*prevchd / CHISQ;
RUN;
PROC FREQ DATA = fghmtemp;
TABLE diabetes*prevchd / CHISQ;
RUN;
PROC FREQ DATA = fghmtemp;
TABLE prevmi*prevchd / CHISQ;
RUN;
PROC FREQ DATA = fghmtemp;
TABLE prevstrk*prevchd / CHISQ;
RUN;
PROC FREQ DATA = fghmtemp;
TABLE prevhyp*prevchd / CHISQ;
RUN;
In this case, we only had a few pairs of variables to compare, but what if you had to do this for 10, 20, or 100 pairs of variables. Writing that code repeatedly would take a while. We can simplify our code by using a MACRO with a loop.
This MACRO has four paramters:
Output: Create a table and output chi-square and Fisher's exact test for each pair of variables.
%MACRO twobytwov2(dataset, predictor, response, n);
%DO i=1 %TO &n;
%LET dep = %SCAN(&predictor, &i);
PROC FREQ DATA = &dataset;
TITLE "&dep vs &response";
TABLE &dep*&response / CHISQ;
RUN;
TITLE;
%END;
%MEND;
%twobytwov2(fghmtemp, prevap diabetes prevmi prevstrk prevhyp, prevchd, 5);
Now that is a much simpler program! The output contains a lot more tests than we actually want though. What if we want just the tables and p-value for the chi-square test from each test, or just a single table with the p-values for each test. In general SAS is verbose and gives us a lot more output than we want. So we will need to select just the parts of the output that we want to make our reports.
Often, we will want to make our MACROS data driven, that means we will want our MACRO to perform different actions depending what data we have. To do this, we will need to use SYMPUT and SYMGET and to use conditional logic %IF/%THEN/%ELSE inside a MACRO.
For the next example, we will update our MACRO to only return the two by two table and either the adjusted chi-square p-value or Fisher's exact test p-value if the expected cell counts are less than 5.
First, we will need to write and test our code for selecting only the output we want before we make our updated macro. We want to run a continuity adjusted chi-square test or Fisher's exact test if the expected counts are too small. We only want the table with row percentages and the result of the correct test in our output.
/*ODS TRACE ON;*/
PROC FREQ DATA = fghmtemp;
TABLE prevap*prevchd / EXPECTED chisq;
ODS OUTPUT CrossTabFreqs = ct ChiSq = chi FishersExact = fet;
RUN;
/*ODS TRACE OFF;*/
/*Lot's of missing data. We only want to use non missing values*/
PROC PRINT DATA = ct;
RUN;
title '/* Test how to clean the resulting datasets */';
PROC PRINT DATA=ct;
WHERE expected < 5 and prevap ne . and prevchd ne .;
RUN;
title;
*Create an indicator variable that is 1 if there is at least one cell with expected count less than 5;
%LET low_count = 0;
DATA _NULL_; *Run through the data set without creating a new one;
SET ct;
IF EXPECTED < 5 and prevap ne . and prevchd ne . THEN CALL SYMPUT('low_count', 1);
RUN;
%PUT &=low_count; *Should show value of 1 in the log file.;
/* Now, that we can check to see if the expected cell counts are less than 5,
* we need to see how we can clean the chi-square or Fisher tables to print only
* the test name and p-value.
*/
PROC PRINT DATA=chi;
RUN;
/*Select the row for the continuity adjusted chi-square test*/
DATA chi2;
SET chi;
WHERE statistic="Continuity Adj. Chi-Square";
DROP TABLE DF VALUE;
RUN;
PROC PRINT DATA = chi2;
RUN;
/*Do the same thing for Fisher's exact test*/
PROC PRINT DATA = fet;
RUN;
DATA fet2 (RENAME = (cValue1 = Prob));
SET fet;
Statistic = "Fisher's Exact Test";
WHERE NAME1 = "XP2_FISH";
KEEP statistic cValue1;
RUN;
DATA fet2;
RETAIN Statistic Prob;
SET fet2;
RUN;
PROC PRINT DATA = fet2;
RUN;
Now, let's make this into a MACRO.
%MACRO twobytwov3(dataset, predictor, response);
%LET n = %LENGTH(predictor);
%LET i = 1;
%LET dep = %SCAN(&predictor, &i);
%DO %WHILE(&dep ne);
PROC FREQ DATA = &dataset;
TABLE &dep*&response / CHISQ EXPECTED;
ODS SELECT NONE;
ODS OUTPUT crosstabfreqs = ct ChiSq = chi FishersExact = fet;
RUN;
PROC FREQ DATA = &dataset;
TITLE "&dep vs &response";
TABLE &dep*&response / NOCOL NOPERCENT;
ODS SELECT CrossTabFreqs;
RUN;
TITLE;
%LET low_count = 0;
DATA _NULL_; *Run through the data set without creating a new one;
SET ct;
IF EXPECTED < 5 and &dep ne . and &response ne . THEN CALL SYMPUT('low_count', 1);
RUN;
%IF &low_count = 0 %THEN %DO;
DATA chi;
SET chi;
WHERE statistic="Continuity Adj. Chi-Square";
DROP TABLE DF VALUE;
RUN;
PROC PRINT DATA = chi;
RUN;
%END;
%ELSE %DO;
DATA fet (RENAME = (cValue1 = Prob));
SET fet;
Statistic = "Fisher's Exact Test";
WHERE NAME1 = "XP2_FISH";
KEEP statistic cValue1;
RUN;
DATA fet;
RETAIN Statistic Prob;
SET fet;
RUN;
PROC PRINT DATA = fet;
RUN;
%END;
ODS STARTPAGE = NOW;
%LET i = %EVAL(&i + 1);
%LET dep = %SCAN(&predictor, &i);
%END;
%MEND;
%twobytwov3(fghmtemp, prevap diabetes prevmi prevstrk prevhyp, prevchd);