Lab 3: Linear Mixed Models in SAS

In this lab, we will focus on repeated measures data. For out examples, we will use the BPRS dataset, which is from a clinical trial studying the effect of two treatments on schizophrenia. In this trial, 40 subjects were randomly assigned to one of two treatment groups and measured on the Brief Psychiatric Rating Scale (BPRS) at baseline and for 8 weeks. We have the following variables:

  • BPRS: 18 item meaure used to screen for schizophrenia (rangeis 18-126)
  • grp: Treatment group 1 or 2
  • id: subject id
  • week: week number 1-8
  • bprs0: initial BPRS score at week 0
In [1]:
*wide form;
data bprs;  
  input id x0-x8;
  grp=1;
  if _n_>20 then grp=2;
  id=100*grp+id;
cards; *datalines;
    1   42  36  36  43  41  40  38  47  51
    2   58  68  61  55  43  34  28  28  28
    3   54  55  41  38  43  28  29  25  24
    4   55  77  49  54  56  50  47  42  46
    5   72  75  72  65  50  39  32  38  32
    6   48  43  41  38  36  29  33  27  25
    7   71  61  47  30  27  40  30  31  31
    8   30  36  38  38  31  26  26  25  24
    9   41  43  39  35  28  22  20  23  21
    10  57  51  51  55  53  43  43  39  32
    11  30  34  34  41  36  36  38  36  36
    12  55  52  49  54  48  43  37  36  31
    13  36  32  36  31  25  25  21  19  22
    14  38  35  36  34  25  27  25  26  26
    15  66  68  65  49  36  32  27  30  37
    16  41  35  45  42  31  31  29  26  30
    17  45  38  46  38  40  33  27  31  27
    18  39  35  27  25  29  28  21  25  20
    19  24  28  31  28  29  21  22  23  22
    20  38  34  27  25  25  27  21  19  21
    1   52  73  42  41  39  38  43  62  50
    2   30  23  32  24  20  20  19  18  20
    3   65  31  33  28  22  25  24  31  32
    4   37  31  27  31  31  26  24  26  23
    5   59  67  58  61  49  38  37  36  35
    6   30  33  37  33  28  26  27  23  21
    7   69  52  41  33  34  37  37  38  35
    8   62  54  49  39  55  51  55  59  66
    9   38  40  38  27  31  24  22  21  21
    10  65  44  31  34  39  34  41  42  39
    11  78  95  75  76  66  64  64  60  75
    12  38  41  36  27  29  27  21  22  23
    13  63  65  60  53  52  32  37  52  28
    14  40  37  31  38  35  30  33  30  27
    15  40  36  55  55  42  30  26  30  37
    16  54  45  35  27  25  22  22  22  22
    17  33  41  30  32  46  43  43  43  43
    18  28  30  29  33  30  26  36  33  30
    19  52  43  26  27  24  32  21  21  21
    20  47  36  32  29  25  23  23  23  23
;
run;

*change to long form;
data bprsl; *longform;
  set bprs;
  array xs x0-x8;
  do week=0 to 8;
    bprs=xs{week+1};
    output;
  end;
  keep id grp week x0 bprs;
run;

*Baseline as covatiate;
data bprslb;
  set bprs;
  array xs x1-x8;
  bprs0=x0;
  do week=1 to 8;
    bprs=xs{week};
    output;
  end;
  keep id grp week bprs0 bprs;
run;

proc print data=bprslb(obs=16) noobs;
run;

SAS Connection established. Subprocess id is 7736
Out[1]:
SAS Output

SAS Output

The SAS System

The PRINT Procedure

Data Set WORK.BPRSLB

id grp bprs0 week bprs
101 1 42 1 36
101 1 42 2 36
101 1 42 3 43
101 1 42 4 41
101 1 42 5 40
101 1 42 6 38
101 1 42 7 47
101 1 42 8 51
102 1 58 1 68
102 1 58 2 61
102 1 58 3 55
102 1 58 4 43
102 1 58 5 34
102 1 58 6 28
102 1 58 7 28
102 1 58 8 28

We will first examine some helpful graphical displays for repeated measure data. There are a few simple guidlines for these plots that will help us choose a model.

  • Show as much of the raw data as possible
  • Highlight aggregate patterns of potential interest
  • Identify both cross-sectional and longitudinal patterns
  • Try to make identification of unusual individuals or observations simple

The first plot is profile plot, also referred to as a spaghetti plot. This plots the responses for each individual over time.

In [2]:
proc sgpanel data=bprsl ;
  panelby grp / spacing=10;
  series y=bprs x=week /group=id ;
  Title 'All subjects by group';
run;
Out[2]:
SAS Output

SAS Output

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

From the graph, we see:

  • BPRS is decreasing on an individual level for almost everyone over the course of the study
  • Those who start higher (or lower) tend to stay higher (or lower)
  • There are individual differences in change

To compare individuals and make it easier to detect outliers, we can plot the standardized values at each time.

In [8]:
proc sort data=bprsl;
 by week;
run;
proc stdize data=bprsl out=bprslz method=std;
  var bprs;
  by week;
run;
proc sgpanel data=bprslz ;
  panelby grp / spacing=10;
  series y=bprs x=week /group=id ;
  title 'standardized scores by time and trt';
run;
Out[8]:
SAS Output

SAS Output

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

With large numbers of observations, much of the information that can be gleaned by looking at individual responses will be obscured. It is often useful to look at mean plots by trt group

In [11]:
proc sgplot data=bprsl;
  vline week / response=bprs stat=mean group=grp limitstat=stderr;
  Title 'Means by week and TRT';
run;
Out[11]:
SAS Output

SAS Output

The SGPLOT Procedure

The SGPlot Procedure

The SGPlot Procedure

To further incorporate variability and outlier information, an alternative to the mean plot could be side-by-side box plots at each time.

In [12]:
proc sgplot data=bprsl;
  vbox bprs / category=week group=grp;* nocaps;
  Title 'Boxplots by week and TRT';
run;
Out[12]:
SAS Output

SAS Output

The SGPLOT Procedure

The SGPlot Procedure

The SGPlot Procedure

Summary Measure Analysis

Before we move on to linear mixed models, I want to breifly discuss a simpler analysis method. Summary measures analysis reduces the repeated measures on each individual (these are correlated) to a single summary measure for each subject that can be used to answer the question of interest. This reduces the dataset to a summary measure for each subject. These new measures are independent and so we can use the methods we already know such as the two sample t-test. For example, consider the following two questions concerning the BPRS dataset:

  1. Is the overall BPRS score different between the treatment groups?
  2. Is the rat of change in the BRPS score different between the treatment groups?

The first question asks of the treatments effect on the response differe while the second question asks if the one treatment causes a faster deacrease in the BPRS score. We can answer the first question using a summary measures analysis by taking the mean brps scores of the 8 weeks as the response for each subject and performing a two sample t-test. For the second question, we can use the setimate slope from a simple linear regression between brps and weeks for each subject and again perform a two sample t-test between the average slopes for each treatment group.

The summary measures analysis for the first question can be done as follows:

In [14]:
data bprsm; *Calculate means using wide dataset;
 set bprs;
 mnbprs=mean(of x1-x8);
run;
proc sgplot data=bprsm;;
  vbox mnbprs / category=grp ;
 Title 'boxplots of mean outomes';
run;
proc ttest data=bprsm;  *t-test for mean outcome;
  class grp;
  var mnbprs;
run;
Out[14]:
SAS Output

SAS Output

The SGPLOT Procedure

The SGPlot Procedure

The SGPlot Procedure

The TTEST Procedure

mnbprs

boxplots of mean outomes

The TTEST Procedure

Variable: mnbprs

Statistics

grp N Mean Std Dev Std Err Minimum Maximum
1 20 36.1688 8.3691 1.8714 24.8750 52.6250
2 20 36.5625 12.2090 2.7300 22.0000 71.8750
Diff (1-2)   -0.3937 10.4667 3.3098    

Confidence Limits

grp Method Mean 95% CL Mean Std Dev 95% CL Std Dev
1   36.1688 32.2519 40.0856 8.3691 6.3646 12.2236
2   36.5625 30.8485 42.2765 12.2090 9.2848 17.8321
Diff (1-2) Pooled -0.3937 -7.0942 6.3067 10.4667 8.5538 13.4892
Diff (1-2) Satterthwaite -0.3937 -7.1229 6.3354      

T-Tests

Method Variances DF t Value Pr > |t|
Pooled Equal 38 -0.12 0.9059
Satterthwaite Unequal 33.626 -0.12 0.9060

Equality of Variances

Equality of Variances
Method Num DF Den DF F Value Pr > F
Folded F 19 19 2.13 0.1083

Summary Panel

Summary Panel for mnbprs

Q-Q Plots

Q-Q Plots for mnbprs

To compare the mean slopes by group, which represents the individual rate of score increase/decline, we do the following.

In [16]:
proc sort data=bprsl;
by id;
run;
proc reg data=bprsl outest=regco noprint;
 by grp id x0 ;
 model bprs=week;
run;
data reggrp; set regco;
   bprsrate=week;
   keep id grp bprsrate x0;
run;

proc sgplot data=reggrp;
  vbox bprsrate / category=grp ;
 Title 'boxplots of mean rates';
run;
proc ttest data=reggrp;  *t-test for reg coef;
  class grp;
  var bprsrate;
run;
Out[16]:
SAS Output

SAS Output

The SGPLOT Procedure

The SGPlot Procedure

The SGPlot Procedure

The TTEST Procedure

bprsrate

boxplots of mean rates

The TTEST Procedure

Variable: bprsrate

Statistics

grp N Mean Std Dev Std Err Minimum Maximum
1 20 -2.6283 1.8740 0.4190 -6.2833 1.1667
2 20 -1.9125 1.5539 0.3475 -4.2333 1.3833
Diff (1-2)   -0.7158 1.7214 0.5444    

Confidence Limits

grp Method Mean 95% CL Mean Std Dev 95% CL Std Dev
1   -2.6283 -3.5054 -1.7513 1.8740 1.4252 2.7372
2   -1.9125 -2.6398 -1.1852 1.5539 1.1817 2.2696
Diff (1-2) Pooled -0.7158 -1.8178 0.3862 1.7214 1.4068 2.2186
Diff (1-2) Satterthwaite -0.7158 -1.8191 0.3874      

T-Tests

Method Variances DF t Value Pr > |t|
Pooled Equal 38 -1.31 0.1964
Satterthwaite Unequal 36.74 -1.31 0.1967

Equality of Variances

Equality of Variances
Method Num DF Den DF F Value Pr > F
Folded F 19 19 1.45 0.4217

Summary Panel

Summary Panel for bprsrate

Q-Q Plots

Q-Q Plots for bprsrate

From the profile plots, recall that we made a few observations about the plot.

  • BPRS is decreasing on an individual level for almost everyone over the course of the study
  • Those who start higher (or lower) tend to stay higher (or lower)
  • There are individual differences in change

There is definitely variability in the intercepts along with some variability in the slopes, so let's fit a random slope model.

In [21]:
PROC MIXED DATA=bprsl method=ML covtest;
CLASS grp id;
MODEL bprs = week grp week*grp/ solution ddfm=satterth outp=pred residual;
RANDOM Intercept week / type=un subject=id  g;
RUN;
Out[21]:
SAS Output

SAS Output

boxplots of mean rates

The Mixed Procedure

The MIXED Procedure

Model Information

Model Information
Data Set WORK.BPRSL
Dependent Variable bprs
Covariance Structure Unstructured
Subject Effect id
Estimation Method ML
Residual Variance Method Profile
Fixed Effects SE Method Model-Based
Degrees of Freedom Method Satterthwaite

Class Level Information

Class Level Information
Class Levels Values
grp 2 1 2
id 40 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220

Dimensions

Dimensions
Covariance Parameters 4
Columns in X 6
Columns in Z per Subject 2
Subjects 40
Max Obs per Subject 9

Number of Observations

Number of Observations
Number of Observations Read 360
Number of Observations Used 360
Number of Observations Not Used 0

Iteration History

Iteration History
Iteration Evaluations -2 Log Like Criterion
0 1 2827.30344284  
1 1 2507.46010271 0.00000000

Convergence Status

Convergence criteria met.

Estimated G Matrix

Estimated G Matrix
Row Effect id Col1 Col2
1 Intercept 101 164.21 -12.5143
2 week 101 -12.5143 2.2027

Covariance Parameter Estimates

Covariance Parameter Estimates
Cov Parm Subject Estimate Standard
Error		 Z Value Pr Z
UN(1,1) id 164.21 39.8393 4.12 <.0001
UN(2,1) id -12.5143 4.2632 -2.94 0.0033
UN(2,2) id 2.2027 0.6316 3.49 0.0002
Residual   36.7474 3.1057 11.83 <.0001

Fit Statistics

Fit Statistics
-2 Log Likelihood 2507.5
AIC (Smaller is Better) 2523.5
AICC (Smaller is Better) 2523.9
BIC (Smaller is Better) 2537.0

Null Model Likelihood Ratio Test

Null Model Likelihood Ratio Test
DF Chi-Square Pr > ChiSq
3 319.84 <.0001

Solution for Fixed Effects

Solution for Fixed Effects
Effect grp Estimate Standard
Error		 DF t Value Pr > |t|
Intercept   45.5944 2.9840 40 15.28 <.0001
week   -1.9125 0.3752 40 -5.10 <.0001
grp 1 2.2911 4.2201 40 0.54 0.5902
grp 2 0 . . . .
week*grp 1 -0.7158 0.5306 40 -1.35 0.1849
week*grp 2 0 . . . .

Type 3 Tests of Fixed Effects

Type 3 Tests of Fixed Effects
Effect Num DF Den DF F Value Pr > F
week 1 40 73.24 <.0001
grp 1 40 0.29 0.5902
week*grp 1 40 1.82 0.1849

Marginal Residual Plots

Residuals

Panel of marginal residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Studentized Residuals

Panel of marginal studentized residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Pearson Residuals

Panel of marginal Pearson residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Conditional Residual Plots

Residuals

Panel of conditional residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Studentized Residuals

Panel of conditional studentized residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Pearson Residuals

Panel of conditional Pearson residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

This model results in the following prediction lines.

In [23]:
proc sgpanel data=bprsl ;
  panelby grp / spacing=10;
  series y=bprs x=week /group=id ;
  Title 'All subjects by group';
run;

PROC SGPANEL data=pred;
    panelby grp/spacing=10;
    series y=pred x = week/group=id;
    title 'Prediction Lines by Group';
RUN;
Out[23]:
SAS Output

SAS Output

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

Dropping the random slope yields

In [24]:
PROC MIXED DATA=bprsl method=ML covtest;
CLASS grp id;
MODEL bprs = week grp week*grp/ solution ddfm=satterth outp=pred residual;
RANDOM Intercept / type=un subject=id  g;
RUN;

proc sgpanel data=bprsl ;
  panelby grp / spacing=10;
  series y=bprs x=week /group=id ;
  Title 'All subjects by group';
run;

PROC SGPANEL data=pred;
    panelby grp/spacing=10;
    series y=pred x = week/group=id;
    title 'Prediction Lines by Group';
RUN;
Out[24]:
SAS Output

SAS Output

Prediction Lines by Group

The Mixed Procedure

The MIXED Procedure

Model Information

Model Information
Data Set WORK.BPRSL
Dependent Variable bprs
Covariance Structure Unstructured
Subject Effect id
Estimation Method ML
Residual Variance Method Profile
Fixed Effects SE Method Model-Based
Degrees of Freedom Method Satterthwaite

Class Level Information

Class Level Information
Class Levels Values
grp 2 1 2
id 40 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220

Dimensions

Dimensions
Covariance Parameters 2
Columns in X 6
Columns in Z per Subject 1
Subjects 40
Max Obs per Subject 9

Number of Observations

Number of Observations
Number of Observations Read 360
Number of Observations Used 360
Number of Observations Not Used 0

Iteration History

Iteration History
Iteration Evaluations -2 Log Like Criterion
0 1 2827.30344284  
1 1 2567.18289277 0.00000000

Convergence Status

Convergence criteria met.

Estimated G Matrix

Estimated G Matrix
Row Effect id Col1
1 Intercept 101 97.5003

Covariance Parameter Estimates

Covariance Parameter Estimates
Cov Parm Subject Estimate Standard
Error		 Z Value Pr > Z
UN(1,1) id 97.5003 23.1299 4.22 <.0001
Residual   53.2679 4.2112 12.65 <.0001

Fit Statistics

Fit Statistics
-2 Log Likelihood 2567.2
AIC (Smaller is Better) 2579.2
AICC (Smaller is Better) 2579.4
BIC (Smaller is Better) 2589.3

Null Model Likelihood Ratio Test

Null Model Likelihood Ratio Test
DF Chi-Square Pr > ChiSq
1 260.12 <.0001

Solution for Fixed Effects

Solution for Fixed Effects
Effect grp Estimate Standard
Error		 DF t Value Pr > |t|
Intercept   45.5944 2.4251 51.6 18.80 <.0001
week   -1.9125 0.2107 320 -9.08 <.0001
grp 1 2.2911 3.4296 51.6 0.67 0.5071
grp 2 0 . . . .
week*grp 1 -0.7158 0.2980 320 -2.40 0.0169
week*grp 2 0 . . . .

Type 3 Tests of Fixed Effects

Type 3 Tests of Fixed Effects
Effect Num DF Den DF F Value Pr > F
week 1 320 232.25 <.0001
grp 1 51.6 0.45 0.5071
week*grp 1 320 5.77 0.0169

Marginal Residual Plots

Residuals

Panel of marginal residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Studentized Residuals

Panel of marginal studentized residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Pearson Residuals

Panel of marginal Pearson residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Conditional Residual Plots

Residuals

Panel of conditional residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Studentized Residuals

Panel of conditional studentized residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Pearson Residuals

Panel of conditional Pearson residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

It looks like there might be some curvilinear pattern in the response curves. Let's just explore adding a cubic term to the model.

In [25]:
PROC MIXED DATA=bprsl method=ML covtest;
CLASS grp id;
MODEL bprs = week week*week week*week*week grp/ solution ddfm=satterth outp=pred residual;
RANDOM Intercept week week*week week*week*week/ type=un subject=id  g;
RUN;

proc sgpanel data=bprsl ;
  panelby grp / spacing=10;
  series y=bprs x=week /group=id ;
  Title 'All subjects by group';
run;

PROC SGPANEL data=pred;
    panelby grp/spacing=10;
    series y=pred x = week/group=id;
    title 'Prediction Lines by Group';
RUN;
Out[25]:
SAS Output

SAS Output

Prediction Lines by Group

The Mixed Procedure

The MIXED Procedure

Model Information

Model Information
Data Set WORK.BPRSL
Dependent Variable bprs
Covariance Structure Unstructured
Subject Effect id
Estimation Method ML
Residual Variance Method Profile
Fixed Effects SE Method Model-Based
Degrees of Freedom Method Satterthwaite

Class Level Information

Class Level Information
Class Levels Values
grp 2 1 2
id 40 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220

Dimensions

Dimensions
Covariance Parameters 11
Columns in X 6
Columns in Z per Subject 4
Subjects 40
Max Obs per Subject 9

Number of Observations

Number of Observations
Number of Observations Read 360
Number of Observations Used 360
Number of Observations Not Used 0

Iteration History

Iteration History
Iteration Evaluations -2 Log Like Criterion
0 1 2822.55699776  
1 2 2409.20271803 0.00000221
2 1 2409.20075746 0.00000000

Convergence Status

Convergence criteria met.

Estimated G Matrix

Estimated G Matrix
Row Effect id Col1 Col2 Col3 Col4
1 Intercept 101 198.12 -36.7907 1.8122 0.1504
2 week 101 -36.7907 68.3865 -17.5914 1.2017
3 week*week 101 1.8122 -17.5914 5.0095 -0.3558
4 week*week*week 101 0.1504 1.2017 -0.3558 0.02567

Covariance Parameter Estimates

Covariance Parameter Estimates
Cov Parm Subject Estimate Standard
Error		 Z Value Pr Z
UN(1,1) id 198.12 48.3609 4.10 <.0001
UN(2,1) id -36.7907 24.1726 -1.52 0.1280
UN(2,2) id 68.3865 20.6872 3.31 0.0005
UN(3,1) id 1.8122 6.3986 0.28 0.7770
UN(3,2) id -17.5914 5.6374 -3.12 0.0018
UN(3,3) id 5.0095 1.6141 3.10 0.0010
UN(4,1) id 0.1504 0.4732 0.32 0.7507
UN(4,2) id 1.2017 0.4113 2.92 0.0035
UN(4,3) id -0.3558 0.1203 -2.96 0.0031
UN(4,4) id 0.02567 0.009082 2.83 0.0024
Residual   20.5722 2.0572 10.00 <.0001

Fit Statistics

Fit Statistics
-2 Log Likelihood 2409.2
AIC (Smaller is Better) 2441.2
AICC (Smaller is Better) 2442.8
BIC (Smaller is Better) 2468.2

Null Model Likelihood Ratio Test

Null Model Likelihood Ratio Test
DF Chi-Square Pr > ChiSq
10 413.36 <.0001

Solution for Fixed Effects

Solution for Fixed Effects
Effect grp Estimate Standard
Error		 DF t Value Pr > |t|
Intercept   48.6122 2.7272 53 17.83 <.0001
week   -2.4839 1.5159 40 -1.64 0.1091
week*week   -0.3659 0.4229 40 -0.87 0.3921
week*week*week   0.05253 0.03166 40 1.66 0.1049
grp 1 -0.5745 2.8587 40 -0.20 0.8417
grp 2 0 . . . .

Type 3 Tests of Fixed Effects

Type 3 Tests of Fixed Effects
Effect Num DF Den DF F Value Pr > F
week 1 40 2.69 0.1091
week*week 1 40 0.75 0.3921
week*week*week 1 40 2.75 0.1049
grp 1 40 0.04 0.8417

Marginal Residual Plots

Residuals

Panel of marginal residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Studentized Residuals

Panel of marginal studentized residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Pearson Residuals

Panel of marginal Pearson residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Conditional Residual Plots

Residuals

Panel of conditional residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Studentized Residuals

Panel of conditional studentized residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

Pearson Residuals

Panel of conditional Pearson residuals for bprs. The panel consists of a scatterplot of the residuals, a histogram with normal density, a Q-Q plot, and summary statistics for the residuals and the model fit.

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure

The SGPANEL Procedure

The SGPanel Procedure

The SGPanel Procedure
In [ ]: